Manage the desktop through native Lua and UWSM with Grid, Monocle, Tabs and Scrolling layouts. Add workspace-local navigation, bounded scrolling focus and a runtime Grid ratio defaulting to 1.20. Configure the HDR OLED and portrait LG, HDMI recovery, NVIDIA suspend handling, independent locking and Plasma fallback. Fix Waybar workspace IPC and provide immediate per-output layout status. Include desktop controls, screenshots, usage documentation and controller/panel regression tests. Use the authorized local illustris flake input.
101 lines
2.7 KiB
Nix
101 lines
2.7 KiB
Nix
{
|
|
description = "A very basic flake";
|
|
|
|
inputs = {
|
|
nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
|
|
home-manager = {
|
|
url = "github:nix-community/home-manager";
|
|
inputs.nixpkgs.follows = "nixpkgs";
|
|
};
|
|
illustris = {
|
|
url = "path:///home/illustris/src/flake";
|
|
inputs = {
|
|
nixpkgs.follows = "nixpkgs";
|
|
firefox-addons.follows = "firefox-addons";
|
|
home-manager.follows = "home-manager";
|
|
};
|
|
};
|
|
nixfs = {
|
|
url = "github:illustris/nixfs";
|
|
inputs.nixpkgs.follows = "nixpkgs";
|
|
};
|
|
nixtop = {
|
|
url = "github:illustris/nixtop";
|
|
inputs.nixpkgs.follows = "nixpkgs";
|
|
};
|
|
firefox-addons = {
|
|
url = "gitlab:rycee/nur-expressions?dir=pkgs/firefox-addons";
|
|
inputs.nixpkgs.follows = "nixpkgs";
|
|
};
|
|
};
|
|
|
|
outputs = { self, nixpkgs, home-manager, illustris, nixfs, nixtop, ... }@inputs: {
|
|
nixosConfigurations = {
|
|
desktop = nixpkgs.lib.nixosSystem {
|
|
system = "x86_64-linux";
|
|
modules = [
|
|
./configuration.nix
|
|
{
|
|
environment.etc.flake.source = self;
|
|
nix.registry.nixpkgs.flake = nixpkgs;
|
|
nixpkgs.overlays = with illustris.overlays; [
|
|
lib
|
|
pkgs
|
|
suckless
|
|
] ++ [
|
|
# TODO: drop when nixpkgs ships wacomtablet's dependency metadata
|
|
# (missing from pkgs/kde/generated/dependencies.json as of 2c423e0)
|
|
(final: prev: {
|
|
kdePackages = prev.kdePackages.overrideScope (kf: kp: {
|
|
wacomtablet = kp.wacomtablet.overrideAttrs (old: {
|
|
nativeBuildInputs = (old.nativeBuildInputs or [ ]) ++ [ kf.extra-cmake-modules ];
|
|
buildInputs = (old.buildInputs or [ ]) ++ (with kf; [
|
|
kcmutils
|
|
kconfig
|
|
kcoreaddons
|
|
kdbusaddons
|
|
kdoctools
|
|
kglobalaccel
|
|
ki18n
|
|
kio
|
|
knotifications
|
|
kwidgetsaddons
|
|
kwindowsystem
|
|
kxmlgui
|
|
libplasma
|
|
plasma5support
|
|
]) ++ [
|
|
final.libX11
|
|
final.libxcb
|
|
];
|
|
});
|
|
});
|
|
})
|
|
];
|
|
}
|
|
home-manager.nixosModules.default
|
|
{
|
|
home-manager = {
|
|
useGlobalPkgs = true;
|
|
backupFileExtension = "hm-bak";
|
|
users.illustris = {...}: {
|
|
disabledModules = [ (illustris + "/homeConfigurations/modules/hyprland") ];
|
|
imports = [
|
|
./modules/hyprland/home.nix
|
|
(import (
|
|
illustris + "/homeConfigurations/profiles/dailyDriver/home.nix"
|
|
) inputs)
|
|
];
|
|
};
|
|
};
|
|
}
|
|
nixfs.nixosModules.nixfs
|
|
{services.nixfs.enable = true;}
|
|
illustris.nixosModules.plasmonad
|
|
{environment.systemPackages = [ nixtop.packages.x86_64-linux.nixtop ];}
|
|
];
|
|
};
|
|
};
|
|
};
|
|
}
|